• Yogurt3D
• Support
• Company

• Showcase
• Downloads
• Engine
• Forum
• Wiki
• Contact
• Logos
• Events
• Jobs
• About Yogurt
• Examples
• Tutorials
• API Docs

Basic Light Tutorial

Tweet

To view this page ensure that Adobe Flash Player version 11.0.0 or greater is installed.

package
{
	import com.yogurt3d.Yogurt3D;
	import com.yogurt3d.core.events.Yogurt3DEvent;
	import com.yogurt3d.core.lights.Light;
	import com.yogurt3d.core.materials.MaterialDiffuseFill;
	import com.yogurt3d.core.materials.MaterialFill;
	import com.yogurt3d.core.sceneobjects.SceneObject;
	import com.yogurt3d.presets.primitives.sceneobjects.BoxSceneObject;
	
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.geom.Vector3D;
	
	[SWF(width="400", height="300")] // initialize SWF size to be 800 by 600
	public class BasicLight extends Sprite
	{
		// We define a SceneObject varible as a member: a box of type BoxSceneObject
		public var box:BoxSceneObject;
		
		// starting point: initialize the Yogurt3D engine
		public function BasicLight()
		{
			Yogurt3D.instance.addEventListener( Yogurt3DEvent.READY, onContextReady );
			// Initilize the Yogurt3D instance
			Yogurt3D.instance.init( this.stage );
		}
		
		// Create the scene and start rendering when the Context3D is ready
		public function onContextReady( _e:Event ):void{
			// Here we initialize the scene. Nothing is drawn onto the screen yet. 
			
			// Initialize the Yogurt3D engine with the default setup (scene, camera, renderer etc.)
			Yogurt3D.instance.defaultSetup(400,300);
			// change the background color of the scene (default scene) to red (0xFF0000 in hex rgb) 
			Yogurt3D.instance.defaultScene.sceneColor = 0xEFEFEF;
			
			// create the actual box object with default parameters (at the origin)
			box = new BoxSceneObject();
			// add material to the box: Green, opaque difuse fill 
			box.material = new MaterialDiffuseFill( 0x00FF00,1 );
			
			// simply add the box to the scene. The box will apperar (be rendered) on the default scene
			Yogurt3D.instance.defaultScene.addChild( box );
			
			// Camera Setup
			// We have the default camera on the scene. Let's change its position to -20 on the z-axis
			Yogurt3D.instance.defaultCamera.transformation.position = new Vector3D( 0,10,-30 );
			// and let the camera look at to the origin (0,0,0)
			Yogurt3D.instance.defaultCamera.transformation.lookAt( new Vector3D );
			
			// Adding Lights
			// We create a new light object with default parameters. 
			// It is directional light, meaning the light rays are parallel as if they are coming from a source at the infinity.
			var light:Light = new Light( Light.DIRECTIONAL_LIGHT );
			// the set the light source position
			light.transformation.position = new Vector3D(-10,45,-10);
			// and it is directed to the scene origin
			light.transformation.lookAt( new Vector3D );
			// add the newly created light object to the scene
			Yogurt3D.instance.defaultScene.addChild( light );
			
			// Now we are ready to render the scene
			// start the rendering
			Yogurt3D.instance.startAutoUpdate();
			// register a callback function to be called before rendering each frame
			Yogurt3D.instance.enginePreUpdateCallback = onEnterFrame;
		}
		
		// this is called before rendering each frame: rotates the box around the y-axis
		public function onEnterFrame( ):void{
			box.transformation.rotationY+=1; // add a rotation of 1 degree
		}
		
	}
}

Copyright © 2010 yogurt3d.com - All rights reserved